Noise budget of LCGT(Default)

with small beam, dc/rf readout, low prg, 30kg mass, 20K mass, 16K suspension

Blue -> to be optimized
Green -> changed from the default values

Off[General::"spell1"]
Off[General::"spell"]

1.Parameters (for LCGT)

1.1 Physical constants

hb=1.05457266912510183 (10^(-34));(* reduced Planck constant (J*s) *)
ω0=1.8 (10^15);
c=2.99792458000000117`*^8;(* speed of light (m/s) *)
Ω=2 π f;
kB=1.38*10^(-23);(* Boltzmann's constant (J/K) *)
g=9.8;(* acceleration of the gravity (m/s^2) *)
Gravity=6.673*10^(-11);(* Gravitational constant (m^3/Kg/s^2) *)
solarmass=1.989*10^(30);(* mass of Sun (Kg) *)
Mpc=365.2422*24*60*60*c*3.26*10^6;(* 1 Mpc (m) *)

1.2 Laser

lambda=1064*10^(-9);(* wavelength (m) *)
P0= 75;(* power into interderometer(W)*)

1.3 Main cavity

l=3*10^3;(* length of cavity (m); maybe 2.7km *)
w0=3*10^(-2); (* beam radius at mirrors (m); can be 4.5cm for a=12.5cm or 5.4cm for a=15cm *)

1.4 Interferometer (see 2.3.2)

Gpower=11;(* power recycling gain; used to be 11; can be 14 *)

1.5 Suspension

lsus=0.4; (* length of wire (m) *)
dwire=0.0018;(* diameter of fiber (m) *)
Np=4;(* number of wire *)
E0wire=4.0*10^(11);(* Young's modulus of wire (Pa) *)
rhowire=4.0*10^3;(* density of wire(kg/m^3) *)
fpen=1/(2*Pi)*Sqrt[g/lsus];(* resonant frequency of pendulum (Hz) *)
Tp=16;(* temperature of suspension (K) *)
phiwire=2*10^(-7);(* loss angle of fiber *)
StringForm["resonant frequency of pendulum is `` Hz",NumberForm[fpen,3]]

1.6 Mirror

rho=4.0*10^3;(* density (kg/m^3) *)
radius=12.5*10^(-2);(* radius (m); used to be 12.5cm; can be 15cm *)
height=15*10^(-2);(* height (m) *)
mass= rho*Pi*radius^2*height;(* mass (kg) *)
Tm=20;(* temperature of mirror (K) *)
E0=4.0*10^(11);(* Young's modulus (Pa) *)
sigma = 0.29;(* Poisson ratio *)
Qmirror=10^(8);(* loss angle of material *)
alpha20=5.6*10^(-9);(* thermal expansion coefficient at 20K (/K) *)
Cth20=0.69;(* specific heat at 20 K (J/kg*K) *)
kappa20=1.57*10^4;(* thermal conductivity at 20 K (W/m*K) *)
alpha300=5.0*10^(-6);(* thermal expansion coefficient of sapphire at 300 K(/K) *)
Cth300=7.9*10^2;(* specific heat of sapphire at 300 K(J/kg*K) *)
kappa300=40;(* thermal conductivity of sapphire at 300 K (W/m*K) *)
dcoa=5*10^(-6);(* thickness of coating (m) *)
phicoa=4*10^(-4);(* loss angle of coating *)
StringForm["mass of a mirror is `` kg",NumberForm[mass,3]]

T300=300;

Additional parameters for TN

Suspension

ϕp=phiwire;

Coating

Solve[0.49^Ncoa *2.8==T,Ncoa]
Solve[0.49^Ncoa *2.8==10*(10^(-6)),Ncoa]

{{Ncoa -> 9.18354}}

{{Ncoa -> 17.5826}}

Ncoa1=9;
Ncoa2=18;

Ys=7.2*10^10;(* Young's modulus for silica (Pa=N/m^2) *)
Yt=1.4*10^11;(* Young's modulus for Ta2O5 (Pa=N/m^2) *)
σs = 0.17;(* Poisson ratio for silica *)
σt = 0.23;(* Poisson ratio for Ta2O5 or sapphire *)
n1=1.45; (* Refraction index of silica *)
n2=2.07; (* Refraction index of tantala *)
dcoa1s=(Ncoa1-1)/4*10^(-6)/n1;(* thickness of ITM silica coating (m) *)
dcoa2s=(Ncoa2-1)/4*10^(-6)/n1;(* thickness of ETM silica coating (m) *)
dcoa1t=Ncoa1/4*10^(-6)/n2;(* thickness of ITM tantala coating (m) *)
dcoa2t=Ncoa2/4*10^(-6)/n2;(* thickness of ETM tantala coating (m) *)
ϕc1=1.0*10^(-4);(* loss angle of silica coating *)
ϕc2=4.0*10^(-4);(* loss angle of tantala coating *)

dcoa1s+dcoa1t
dcoa2s+dcoa2t

The following numbers are for the room temperature.

Cs=1.64 10^6;
κs=1.38/Cs;
αexps=5.1 10^-7;
Ct=2.1 10^6;
κt=33/Ct;
αexpt=3.6 10^-6;

Csap300=Cth300*rho;

lightwave=1064*(10^(-9));
β1=8*(10^(-6)); (* silica; taken from Evans 2008 *)
β2=14*(10^(-6)); (* tantala; taken from Evans 2008 *)

βref=(((n1^2)β2+(n2^2)β1)/(4((n2^2)-(n1^2))));

Averaging (R and γc are averaged without the notation "Av.")

CcAv:=Ct(coat/(coa+coat))+Cs(coa/(coa+coat));

κcAv:=(1/CcAv)((((1/(κt Ct))(coat/(coa+coat))+(1/(κs Cs))(coa/(coa+coat))))^(-1));

ξAv := Sqrt[2 Ω/κcAv]*(coa+coat); (* Averaged *)

R:=(((Sqrt[κcAv]) CcAv)/((Sqrt[κs]) Cs)); (* Averaged *)

2.Optical readout noise

2.1 Additional parameter settings

m=mass; (* test mass (kg) *)
L=l; (* arm length (m) *)
T=0.004; (* ITM transmittance in power; optimal for NSNS w/detune is 0.012 *)
I0=P0*Gpower; (* incident power to the beamsplitter *)
ρ=(Sqrt[0.77]); (* SRM reflectivity *)
ζ=π/2*(80/90); (* readout phase; largest signal at π/2; changed for dc readout *)
ϕ=π/2; (* detune phase; BRSE = π/2 *)
StringForm["finesse is `` ",NumberForm[2π/T,4]]

2.2 Basic equations for RSE

hSQL=(Sqrt[((8 hb)/(m (Ω^2) (L^2)))]);

Sh=((hSQL^2)/(2 κ))(((Abs[C11 Sin[ζ]+C21 Cos[ζ]])^2)+((Abs[C12 Sin[ζ]+C22 Cos[ζ]])^2)+((Abs[P12 Sin[ζ]+P22 Cos[ζ]])^2)+((Abs[P11 Sin[ζ]+P21 Cos[ζ]])^2)+((Abs[Q12 Sin[ζ]+Q22 Cos[ζ]])^2)+((Abs[Q11 Sin[ζ]+Q21 Cos[ζ]])^2)+((Abs[N11 Sin[ζ]+N21 Cos[ζ]])^2)+((Abs[N12 Sin[ζ]+N22 Cos[ζ]])^2)+(((Abs[M]*(Sqrt[Sadd])))^2))/((τ^2) ((Abs[D1 Sin[ζ]+D2 Cos[ζ]])^2));

M=1+(ρ^2)Exp[4 I β]-2ρ(Cos[2ϕ]+(κ/2)Sin[2ϕ])Exp[2 I β]+λSR ρ(-ρ Exp[2 I β]+Cos[2ϕ]+(κ/2)Sin[2ϕ])Exp[2 I β]+ϵ ρ(2((Cos[β])^2)(-ρ Exp[2 I β]+Cos[2ϕ])+(κ/2)(3+Exp[2 I β])Sin[2ϕ])Exp[2 I β];
C11=(Sqrt[1-λPD])((1+(ρ^2)) (Cos[2 ϕ]+(κ/2) Sin[2 ϕ])-2 ρ Cos[2 β]-(1/4)ϵ(-2(((1+Exp[2 I β]))^2)ρ+4(1+(ρ^2))((Cos[β])^2)Cos[2ϕ]+(3+Exp[2 I β])κ(1+(ρ^2))Sin[2 ϕ])+λSR(Exp[2 I β]ρ-(1/2)(1+(ρ^2))(Cos[2 ϕ]+(κ/2)Sin[2ϕ])));
C12=(Sqrt[1-λPD])(τ^2) ( -Sin[2 ϕ]-κ  ((Sin[ϕ])^2)+(1/2)ϵ Sin[ϕ]((3+Exp[2 I β])κ Sin[ϕ]+4 ((Cos[β])^2)Cos[ϕ])+(1/2)λSR(Sin[2ϕ]+κ ((Sin[ϕ])^2)));
C21=(Sqrt[1-λPD])(τ^2) (Sin[2 ϕ]-κ  ((Cos[ϕ])^2)+(1/2)ϵ Cos[ϕ]((3+Exp[2 I β])κ Cos[ϕ]+4 ((Cos[β])^2)Sin[ϕ])+(1/2)λSR(-Sin[2ϕ]+κ ((Cos[ϕ])^2))) ;
C22=C11;
D1=(Sqrt[1-λPD])(-(1+ρ Exp[2 I β]) Sin[ϕ]+(1/4)ϵ(3+ρ+2ρ Exp[4 I β]+(1+5ρ)Exp[2 I β])Sin[ϕ]+(1/2)λSR Exp[2 I β]ρ Sin[ϕ]);
D2=(Sqrt[1-λPD])(-(-1+ρ Exp[2 I β]) Cos[ϕ]+(1/4)ϵ(-3+ρ+2ρ Exp[4 I β]+(-1+5ρ)Exp[2 I β])Cos[ϕ]+(1/2)λSR Exp[2 I β]ρ Cos[ϕ]);
P11=(1/2)(Sqrt[1-λPD])(Sqrt[λSR])τ(-2ρ Exp[2 I β]+2Cos[2ϕ]+κ Sin[2ϕ]);
P12=-(Sqrt[1-λPD])(Sqrt[λSR])τ Sin[ϕ](2Cos[ϕ]+κ Sin[ϕ]);
P21=(Sqrt[1-λPD])(Sqrt[λSR])τ Cos[ϕ](2Sin[ϕ]-κ Cos[ϕ]);
P22=P11;
Q11=(Sqrt[λPD])(Exp[-2 I β]+(ρ^2)Exp[2 I β]-ρ(2 Cos[2ϕ]+κ Sin[2 ϕ])+(1/2)ϵ ρ(Exp[-2 I β]Cos[2ϕ]+Exp[2 I β](-2ρ-2ρ Cos[2 β]+Cos[2ϕ]+κ Sin[2ϕ])+2 Cos[2ϕ]+3 κ Sin[2ϕ])-(1/2)λSR ρ(2ρ Exp[2 I β]-2 Cos[2ϕ]-κ Sin[2ϕ]));
Q12=0;
Q21=0;
Q22=Q11;
N11=(Sqrt[1-λPD])(Sqrt[(ϵ/2)])τ(κ(1+ρ Exp[2 I β])Sin[ϕ]+2Cos[β](Exp[-I β]Cos[ϕ]-ρ Exp[I β](Cos[ϕ]+κ Sin[ϕ])));
N12=-(Sqrt[1-λPD])(Sqrt[2 ϵ])τ(-Exp[-I β]+ρ Exp[I β])Cos[β]Sin[ϕ];
N21=-(Sqrt[1-λPD])(Sqrt[2 ϵ])τ(Exp[-I β]+ρ Exp[I β])Cos[β]Cos[ϕ];
N22=(Sqrt[1-λPD])(Sqrt[(ϵ/2)])τ(-κ(1+ρ)Cos[ϕ]+2Cos[β](Exp[-I β]+ρ Exp[I β])Cos[β] Sin[ϕ]);

γ=T c/(4 L);(* cavity pole *)
τ=(Sqrt[1-(ρ^2)]); (* SRM transmittance *)
β=ArcTan[Ω/γ]; (* phase shift in the arm cavity *)
κ=((2 (I0/ISQL) (γ^4))/((Ω^2) ((γ^2)+(Ω^2)))); (* coefficient that shows how much the mirror moves *)
ISQL=((m (L^2) (γ^4))/(4 ω0)); (* the power with which the quantum noise reaches the SQL at the cavity pole frequency *)

2.3 Loss parameters (changed to dc readout)

2.3.1 losses

roundtriploss=70*10^(-6); (* ppm *)
ϵ = 2/T*roundtriploss; (* loss parameter of arms defined in KLMTV paper *)
λSR =0.02; (* loss in power at the signal recycling mirror *)
λPD=0.1;  (* 1 - PD's quantum efficiency in power *)
Sadd= 0*((π^2)/8 - 1); (* ((nonstationary shot noise)/(original shot noise))^2 ; SQW demod -> (π^2)/8 - 1, Sin-wave demod -> 0.5, optimized demod with 3rd harmonics -> 9(π^2)/80 - 1  *)

2.3.2 arm reflectivity and maximum PRG (new)

rArm=-rF+(((tF^2) rE)/(1-rF rE))/.{tF->(Sqrt[1-(rF^2)-20 (10^(-6))])}/.rF->(Sqrt[1-T])/.rE->(Sqrt[1-50*(10^(-6))]);
rArm^2
(rPR^2)/.Solve[(tPR/(1-rArm rPR))==(Sqrt[Gpower+3])/.tPR->(Sqrt[1-(rPR^2)-500 (10^(-6))]),rPR]

Cooling ability is about 1 kW per mirror. Absorption is 20 ppm/cm, i.e. 300 ppm per mirror.
With a safety factor of 3, the input power on the BS should be less than 2 kW.

FindMaximum[((((tPR/(1-rArm rPR))))^2)/.tPR->(Sqrt[1-(rPR^2)-500 (10^(-6))]),{rPR,0.9,0.99}]

P0*14.635

3.Thermal noise

3.1 Suspension by Yamamoto 090618

n=Np;

Icwire=Pi*(dwire/2)^4/4;(* moment of cross section (m^4) *)

ksus[f_]:=Sqrt[(-mass*g/n+Sqrt[(mass*g/n)^2+4*E0wire*(1+I phiwire)*Icwire*rhowire*Pi*(dwire/2)^2*(2*Pi*f)^2])/(2*E0wire*(1+I phiwire)*Icwire)];

kele[f_]:=Sqrt[(mass*g/n+Sqrt[(mass*g/n)^2+4*E0wire*(1+I phiwire)*Icwire*rhowire*Pi*(dwire/2)^2*(2*Pi*f)^2])/(2*E0wire*(1+I phiwire)*Icwire)]

Ksusp[f_]:=n*(2*Pi*f)Sqrt[rhowire*Pi*(dwire/2)^2*E0wire*(1+I phiwire)*Icwire]*(2*Pi*f)^2*Sqrt[(mass*g/n)^2+4*E0wire*(1+I phiwire)* Icwire*rhowire*Pi*(dwire/2)^2*(2*Pi*f)^2]*(ksus[f]*Sin[ksus[f]*lsus]+kele[f]*Cos[ksus[f]*lsus]*Tanh[kele[f]*lsus])/(mass*g/n*(2*Pi*f)^2*Sin[ksus[f]*lsus]*Tanh[kele[f]*lsus]-2*(2*Pi*f)^3*Sqrt[rhowire*Pi*(dwire/2)^2*E0wire*(1+I phiwire)*Icwire]*(Cos[ksus[f]*lsus]-1/Cosh[kele[f]*lsus]));

hsusp[f_]:=2/l*Sqrt[4*kB*Tp/(2*Pi*f)^2*Re[I*2*Pi*f/(Ksusp[f]-mass*(2*Pi*f)^2)]];

hsusp300[f_]=2/l*Sqrt[4*kB*T300/(2*Pi*f)^2*Re[I*2*Pi*f/(Ksusp[f]-mass*(2*Pi*f)^2)]];

3.2 Mirror

3.2.1 Mirror (homogeneous structural damping)

hmirrorstr[f_]:=2/l*Sqrt[4*kB*Tm*(1-sigma^2)/(Sqrt[Pi]*E0*w0*Qmirror*2*Pi*f)];

hmirrorstr300[f_]:=2/l*Sqrt[4*kB*T300*(1-sigma^2)/(Sqrt[Pi]*E0*w0*Qmirror*2*Pi*f)];

Same Q is assumed in the room temperature.

3.2.2 Mirror (thermoelastic damping)

hmirrorthermo[f_]:=2/l*Sqrt[2/Sqrt[Pi]*alpha20^2*(1+sigma)^2*kB*Tm^2*Sqrt[1/(kappa20*rho*Cth20)]/Sqrt[2*Pi*f]];

hmirrorthermo300[f_]:=2/l*Sqrt[8*2/Sqrt[Pi]*alpha300^2*(1+sigma)^2*kB*T300^2*kappa300/(rho*Cth300)^2*(1/w0^3)/(2*Pi*f)^2];

3.2.3 Mirror (coating: structural damping)

hmirrorcoa[f_] := 2/l*Sqrt[8*kB*Tm*(1 + sigma)*(1 - 2*sigma)*dcoa*phicoa/(Pi*w0^2*E0*2*Pi*f)]

hmirrorcoa[f_]=((Sqrt[2])/L)√(((4 kB Tm (dcoa1s+dcoa2s) ϕc1)/(π (w0^2)Ω))(((Ys^2)(((1+sigma))^2)(((1-2sigma))^2)+(E0^2)(((1+σs))^2)(1-2σs))/((E0^2)Ys(1-((σs)^2))))+((4 kB Tm (dcoa1t+dcoa2t) ϕc2)/(π (w0^2)Ω))(((Yt^2)(((1+sigma))^2)(((1-2sigma))^2)+(E0^2)(((1+σt))^2)(1-2σt))/((E0^2)Yt(1-((σt)^2)))));

hmirrorcoa[100]

coating thermal noise of Yamamoto-san's document is 1.2*(10^(-24)).

hmirrorcoa300[f_]=((Sqrt[2])/L)√(((4 kB T300 (dcoa1s+dcoa2s) ϕc1)/(π (w0^2)Ω))(((Ys^2)(((1+sigma))^2)(((1-2sigma))^2)+(E0^2)(((1+σs))^2)(1-2σs))/((E0^2)Ys(1-((σs)^2))))+((4 kB T300 (dcoa1t+dcoa2t) ϕc2)/(π (w0^2)Ω))(((Yt^2)(((1+sigma))^2)(((1-2sigma))^2)+(E0^2)(((1+σt))^2)(1-2σt))/((E0^2)Yt(1-((σt)^2)))));

3.2.4 Thermo-optic noise (infinite-size approximation); this is for the room temperature

ΔαAv:=(αexpt((1+sigma)/(1-σt))(((1+σt)/(1+sigma))+(1-2sigma)(Yt/E0)))(coat/(coa+coat))+αexps((1+sigma)/(1-σs))(((1+σs)/(1+sigma))+(1-2sigma)(Ys/E0))(coa/(coa+coat))-2alpha300(1+sigma)(CcAv/Csap300);
StoAv:=((2 kB (T300^2))/Ω)(1/(π (w0^2)))(1/CcAv)(1/(ξAv (coa+coat)))(1/(ΓD))(Γ0 (((ΔαAv (coa+coat)))^2)-Γ1 ΔαAv (coa+coat) βref lightwave ξAv+Γ2(((βref lightwave))^2)((ξAv)^2));
Γ0:=(2(Sinh[ξAv]-Sin[ξAv])+2R(Cosh[ξAv]-Cos[ξAv]));
Γ1:=8Sin[ξAv/2](R Cosh[ξAv/2]+Sinh[ξAv/2]);
Γ2:=((1+(R^2))Sinh[ξAv]+(1-(R^2))Sin[ξAv]+2R Cosh[ξAv]);
ΓD:=(1+(R^2))Cosh[ξAv]+(1-(R^2))Cos[ξAv]+2R Sinh[ξAv];

hTO1=((Sqrt[2])/L)(Sqrt[StoAv])/.{coa->dcoa1s,coat->dcoa1t}; (* ITM *)
hTO2=((Sqrt[2])/L)(Sqrt[StoAv])/.{coa->dcoa2s,coat->dcoa2t}; (* ETM *)
hTO300[f_]=(Sqrt[(hTO1^2)+(hTO2^2)]);

3.2.5 Total (low temperature; TO is ignored)

hmirror[f_]:=Sqrt[hmirrorstr[f]^2+hmirrorthermo[f]^2+hmirrorcoa[f]^2];

3.2.6 Total (room temperature)

hmirror300[f_]:=Sqrt[hmirrorstr300[f]^2+hmirrorthermo300[f]^2+hmirrorcoa300[f]^2+hTO300[f]^2];

4. Seismic motion

Gseismic[f_]:=10^(-9)/f^2;(* seismic motion (m/Hz^(1/2)) *)

Hiso[f_]:=10^(-3)/f^6;(* total isolation ratio *)

hseis[f_]:=2/l*Gseismic[f]*Hiso[f];

hseis[f]

5.Total

htotal[f_]:=Sqrt[Sh+hsusp[f]^2+hmirror[f]^2+hseis[f]^2];

htotal300[f_]:=Sqrt[Sh+hsusp300[f]^2+hmirror300[f]^2+hseis[f]^2];

6.Graph

P1=LogLogPlot[(Sqrt[Sh]),{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))},PlotStyle->Hue[0.1]];
P2=LogLogPlot[hsusp[f],{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))},PlotStyle->Hue[0.3]];
P2room=LogLogPlot[hsusp300[f],{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))},PlotStyle->Hue[0.3]];
P3=LogLogPlot[hmirror[f],{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))},PlotStyle->Hue[0.7]];
P3room=LogLogPlot[hmirror300[f],{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))},PlotStyle->Hue[0.7]];
P4=LogLogPlot[hseis[f],{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))},PlotStyle->Hue[0.9]];
P5=LogLogPlot[htotal[f],{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))},PlotStyle->Hue[0.5]];
P5room=LogLogPlot[htotal300[f],{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))},PlotStyle->Hue[0.5]];
PSQL=LogLogPlot[hSQL,{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))}];

Show[P1,P2, P3, P4,P5,PSQL]

Show[P1,P2room, P3room, P4,P5room,PSQL]

LogLogPlot[{hmirrorcoa300[f],hTO300[f],hmirrorthermo300[f],hmirrorstr300[f]},{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))}]

Export["hmirrorcoa.m",hmirrorcoa[f]];
Export["hmirrorcoa300.m",hmirrorcoa300[f]];
Export["hTO300.m",hTO300[f]];
Export["hmirrorstr.m",hmirrorstr[f]];
Export["hmirrorstr300.m",hmirrorstr300[f]];
Export["hmirrorthermo.m",hmirrorthermo[f]];
Export["hmirrorthermo300.m",hmirrorthermo300[f]];
Export["hmirror.m",hmirror[f]];
Export["hmirror300.m",hmirror300[f]];
Export["hsuspYama.m",hsusp[f]];
Export["hsuspYama300.m",hsusp300[f]];
Export["hseis.m",hseis[f]];

7.Observable distance (Compact binary coalescense)

7.1 Parameters

m1=1.4*solarmass;(* mass of a compact object (Kg) *)
m2=1.4*solarmass;(* mass of other compace object (Kg) *)
mtotal=m1+m2;(* total moss of binary system (Kg) *)
mreduce=m1*m2/mtotal;(* reduced mass of binary system (Kg) *)
fmin=20;(* low cut off frequency of integral (Hz) *)
fmax=c^3/(6^(3/2)*Pi*Gravity*mtotal);(* high cut off frequency of integral (Hz) *)
SNR=10;(* threshold of Signal to Noise Ratio *)

7.2 Observable distance (Optimal case)

distanceLCGT=(1/SNR)/Sqrt[2]*2*(Gravity/c^3)^(5/6)*c*(5/96*mreduce)^(1/2)*(mtotal/Pi^2)^(1/3)*Sqrt[4*NIntegrate[1/(f^(7/3)*htotal[f]^2),{f,fmin,fmax}]]/Mpc;
StringForm["Observable distance is `` Mpc. ",NumberForm[distanceLCGT,6]]

distanceLCGT*Sqrt[2]

7.3 Observable distance (Definition of LIGO)

distanceLCGT2=1/8*(1/2)*(32/7)^(1/3)*(Gravity/c^3)^(5/6)*c*(5/96*mreduce)^(1/2)*(mtotal/Pi^2)^(1/3)*Sqrt[4*NIntegrate[1/(f^(7/3)*htotal[f]^2),{f,fmin,fmax}]]/Mpc;
StringForm["Observable distance (LIGO definition) is `` Mpc. ",NumberForm[distanceLCGT2,6]]

distanceLCGT2*Sqrt[2]